
################################################################################
# INCLUDE Packages
################################################################################

defineTest( qt ) {
  QT += opengl network script sql
  export(QT)
}

defineTest( glew ) {
  INCLUDEPATH *= /sw/include/GL
  export(INCLUDEPATH)
  LIBS *= -L/opt/local/lib/ -lGLEW
  export(LIBS)
}

defineTest( glut ) {
  INCLUDEPATH *= /System/Library/Frameworks/GLUT.framework/Headers
  export(INCLUDEPATH)
  LIBS *= -framework GLUT
  export(LIBS)
}

defineTest( openmesh ) {
  QMAKE_LIBDIR += $${TOPDIR}/lib
  QMAKE_LIBDIR += $${TOPDIR}/lib
 
  CONFIG( debug, debug|release ){
    LIBS += -lOpenMeshToolsd
    LIBS += -lOpenMeshCored
  } else {
    LIBS += -lOpenMeshTools
    LIBS += -lOpenMeshCore
  }
  export(QMAKE_LIBDIR)
  export(LIBS)
}
